The Backus-Naur form (BNF) (also known as Backus normal form) is a metasyntax used to express context-free grammars: that is, a formal way to describe formal languages. BNF is widely used as a notation for the grammars of computer programming languages, command sets and communication protocols. They can also be used as a notation for representing parts of natural language grammars. For example see the grammar for meter in Venpa poetry. Most textbooks for programming language theory and/or semantics document the programming language in BNF. Some variants, for example ABNF, have their own documentation.

BNF was originally named after John Backus and later (at the suggestion of Donald Knuth) also after Peter Naur. They were two pioneers in computer science, especially in the art of compiler design. BNF was created as part of creating the rules for Algol 60.

Contents

1 Introduction 2 Example 3 Further examples 4 Variants 5 See also 6 References 7 External links

Introduction

A BNF specification is a set of derivation rules, written as

<symbol> ::= <expression with symbols>

where <symbol> is a nonterminal, and the expression consists of sequences of symbols and/or sequences separated by the vertical bar, '|', indicating a choice, the whole being a possible substitution for the symbol on the left. Symbols that never appear on a left side are terminals.

Example

As an example, consider this BNF for a US postal address:

<postal-address> ::= <name-part> <street-address> <zip-part>

<personal-part> ::= <first-name> | <initial> "."

<name-part> ::= <personal-part> <last-name> [<jr-part>] <EOL> | <personal-part> <name-part>

<street-address> ::= [<apt>] <house-num> <street-name> <EOL>

<zip-part> ::= <town-name> "," <state-code> <ZIP-code> <EOL>

This translates into English as:

"A postal-address consists of a name-part, followed by a street-address part, followed by a zip-code part. A personal-part consists of either a first name or an initial followed by a dot. A name-part consists of either: a personal-part followed by a last name followed by an optional "jr-part" (Jr., Sr., or dynastic number) and end-of-line, or a personal part followed by a name part (this rule illustrates the use of recursion in BNFs, covering the case of people who use multiple first and middle names and/or initials). A street address consists of an optional apartment specifier, followed by a street number, followed by a street name. A zip-part consists of a town-name, followed by a comma, followed by a state code, followed by a ZIP-code followed by an end-of-line."

Note that many things (such as the format of a personal-part, apartment specifier, or ZIP-code) are left unspecified here. If necessary, they may be described using additional BNF rules, or left as abstraction if irrelevant for the purpose at hand.

Further examples

Interestingly enough, BNF's syntax may be represented in BNF as follows:

<syntax> ::= <rule> [<syntax>]
<rule> ::= <whitespace> "<" <rule-name> ">" <whitespace> "::=" <expression> <whitespace> <line-end>
<expression> ::= <whitespace> <or-expression>
<or-expression> ::= <whitespace> <list-expression> [ "|" <or-expression> ]
<list-expression> ::= <whitespace>  ("<" <rule-name> ">" | <QUOTE> <text> <QUOTE> | "(" <expression> ")" | "[" <expression> "]") [<list-expression>]
<whitespace> ::= [" " <whitespace>]
<line-end> ::= [<whitespace>] <EOL> [<line-end>]

This assumes that no whitespace is necessary for proper interpretation of the rule. <QUOTE> is presumed to be the " character, and <EOL> to be a carriage-return/line-feed. <rule-name> and <text> are to be substituted with a declared rule's name/label or literal text, respectively.

Variants

There are many variants and extensions of BNF, possibly containing some or all of the regexp wild cards such as "*" or "+". The Extended Backus-Naur form (EBNF) is a common one. In fact the example above isn't the pure form invented for the ALGOL 60 report. The bracket notation "[ ]" was introduced a few years later in IBM's PL/I definition but is now universally recognised. ABNF is another extension commonly used to describe IETF protocols.

Parsing expression grammars build on the BNF and regular expression notations to form an alternative class of formal grammar, which is essentially analytic rather than generative in character.

See also

• Syntax diagram

References

External links

• [1] (http://compilers.iecc.com/comparch/article/93-07-017) contains a posting on news:comp.compilers that explains some of the history of the two names (Backus-Naur form vs. Backus normal form).
• Article BNF and EBNF: What are they and how do they work? (http://www.garshol.priv.no/download/text/bnf.html) by Lars Marius Garshol

de:Backus-Naur-Form fr:Forme de Backus-Naur nl:Backus-Naur Formalisme ja:BNF記法 pl:Notacja BNF tr:Backus-Naur form zh:巴科斯范式